Bryce Kinnamon - Senior Computer Systems Architect

Here’s what the script does (in this order):

1. Reads Servers from a txt file you create on C:\ into a loop.
2. The script pings the server to verify it’s reachable.
3. Then Copies the ‘cleanMOM.exe’ tool and ‘MOMclean.bat’ (which you will create) to ‘c:\’ on the remote server
4. Then the script creates a remote process ‘Win32_Process’ on the server through WMI for the command line. 
5. The remote computer then runs the ‘MOMclean.bat’ file locally which has the necessary switches for the cleanMOM.exe utility to completely remove the SCOM agent from the server.
6. The ‘MOMclean.bat’ then removes the ‘cleanMOM.exe’ utility as well as the batch itself from the remote server. 
7. Then the script creates and writes to a text file ‘c:\success.txt’ all the computers that successfully passed the ping test and should be cleaned of the SCOM agent.
8. Finally you should get this message when the script is complete:

The message states to make sure you go back and delete the gray inactive agents from the console. (you may need to clear your Operations Console cache before you will see the agents go gray).  

See the comments section in the top of the Script file for more detailed instructions regarding the MOMClean.bat and where to get the ‘cleanMOM.exe’ utility. 

The script doesn’t take very long to run at all.  Maybe 5 seconds per server approximately.  Start with some smaller groups to test it out for yourself but once you’re comfortable with it, you can run as many servers as you want at one time.

/////////////////////////////////Here's the script\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 4.1
'
' NAME: Bulk_MOMClean for SCOM
'
' AUTHOR: Bryce Kinnamon (aka Script Money)
' DATE  : 04/24/2008
'
' COMMENTS: Create "C:\Servers.txt" file with the servers you want to clean (one server per line)
'          Get the Resouce Kit from MS (http://www.microsoft.com/downloads/details.aspx?familyid=14FF7073-C71B-4AD0-805A-A8E458D2C9E0&displaylang=en)
'          Copy CleanMOM.exe tool from the resource kit "C:\"
'          Create "C:\MOMClean.bat" and copy these lines into the file:
'     c:\SCOM_Cleanup\cleanMOM.exe /cleanagents
'
'     rd c:\SCOM_Cleanup /s /q
'
'     del /q c:\MOMClean.bat
'
'!!!!!!!!!You will still need to delete the gray inactive agents from the SCOM console, under administration/Agent Managed
'
'*****Obviously you will need an account with the appropriate permissions to run this script.      
'==========================================================================

On Error Resume Next

'''Set File System Objects
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile ("c:\servers.txt", 1, True)
objFSO.CreateTextFile "c:\Success.txt"
Set objtextFile2 = objFSO.OpenTextFile ("c:\Success.txt", 8, False)

''''Start the Loop
Do Until objTextFile.AtEndOfStream
    strComputer = objTextFile.ReadLine
    If isAlive(strComputer) Then 
    strDestination = "\\" & strComputer & "\c$\SCOM_Cleanup\"
   
   ''''If the folder already exists than get it
    If ObjFSO.FolderExists(strDestination)= False Then      
      Set objFolder = objFSO.CreateFolder(strDestination)      
    Set objFolder = objFSO.GetFolder(strDestination)
  Else
      Set objFolder = objFSO.GetFolder(strDestination)
  End If
  
 ''''Copy WMIDiag.vbs file
 objFSO.copyfile "C:\cleanMOM.exe", strDestination, True
 objFSO.copyfile "C:\MOMClean.bat", "\\" & strComputer & "\c$\", True
 
 
 '''' Connect to WMI
 set objWMIService = getobject("winmgmts://" & strComputer & "/root/cimv2")
 strExe = "c:\MOMClean.bat"
 
 '''' Obtain the Win32_Process class of object.
 Set objProcess = objWMIService.Get("Win32_Process")
  Set objProgram = objProcess.Methods_("Create").InParameters.SpawnInstance_
  objProgram.CommandLine = strExe 
 
 'Write succesfully pinged computers to C:\Success.txt
 
 objTextFile2.WriteLine(strComputer) 
  
 'Execute the program now at the command line on the remote computer.
  Set strShell = objWMIService.ExecMethod( _
  "Win32_Process", "Create", objProgram)

End If
Loop

objTextFile.Close
objTextFile2.Close
Set objFSO=Nothing
Set objTextFile=Nothing
Set objtextFile2=Nothing
Set objFolder=Nothing
Set objWMIService=Nothing
Set objProcess=Nothing
Set objProgram=Nothing
Set strShell=Nothing

MsgBox("MOM Bulk Clean has completed.  Please check 'c:\Success.txt' to see the list of servers the script ran on.  Also make sure to delete the gray inactive agents from the Operations Console under 'Administration\Agent Managed'.")

WScript.Quit

Function IsAlive(strHost)
'---------- Test to see if host or url alive through ping -----------------
' Returns True if Host responds to ping
'
' Though there are other ways to ping a computer, Win2K,
' XP and different versions of PING return different error
' codes. So the only reliable way to see if the ping
' was sucessful is to read the output of the ping
' command and look for "TTL="
'
' strHost is a hostname or IP
    Const OpenAsASCII = 0
     Const FailIfNotExist = 0
     Const ForReading =  1
     Dim objShell, objFSO, sTempFile, fFile
    Set objShell = CreateObject("WScript.Shell")
     Set objFSO = CreateObject("Scripting.FileSystemObject")
    sTempFile = objFSO.GetSpecialFolder(2).ShortPath & "\" & objFSO.GetTempName
    objShell.Run "%comspec% /c ping.exe -n 2 -w 500 " & strHost & ">" & sTempFile, 0 , True
    Set fFile = objFSO.OpenTextFile(sTempFile, ForReading, FailIfNotExist, OpenAsASCII)
    x=fFile.ReadAll
    Select Case InStr(x, "TTL=")
         Case 0
            IsAlive = False
         Case Else
            IsAlive = True
    End Select
  
    fFile.Close
     objFSO.DeleteFile(sTempFile)
    Set objFSO = Nothing
    Set objShell = Nothing
End Function